Change in Final Energy Consumption for Air transport mode, EEA33, 1990-2017

PREFIX sdmx-measure: <http://purl.org/linked-data/sdmx/2009/measure#> 
PREFIX sdmx-dimension: <http://purl.org/linked-data/sdmx/2009/dimension#>
PREFIX sdmx-attribute: <http://purl.org/linked-data/sdmx/2009/attribute#> 
PREFIX skos: <http://www.w3.org/2004/02/skos/core#> 
PREFIX property: <http://rdfdata.eionet.europa.eu/eurostat/property#> 
PREFIX unit: <http://dd.eionet.europa.eu/vocabulary/eurostat/unit/>
PREFIX siec: <http://dd.eionet.europa.eu/vocabulary/eurostat/siec/>
PREFIX nrg_bal: <http://dd.eionet.europa.eu/vocabulary/eurostat/nrg_bal/>
PREFIX geo: <http://dd.eionet.europa.eu/vocabulary/eurostat/geo/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>


SELECT 
?nrg_bal_label as ?indic_nrg
'EEA-33' as ?ugeo
round((( SUM(?last_year)-SUM(?first_year) ) / SUM(?first_year) )*1000)/10.0 as ?obsValue

{{

SELECT distinct
  bif:either(?nrg_bal in (nrg_bal:INTAVI, nrg_bal:FC_TRA_DAVI_E), 'Air Domestic/International', ?nrg_bal_label) as ?nrg_bal_label
 #?nrg_bal_label
 bif:either(year(?date) = 1990, SUM(?obsValue), 0) as ?first_year
  bif:either(year(?date) = 2017, SUM(?obsValue), 0) as ?last_year

WHERE {
  {
    GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_bal_c.rdf.gz> 
      {

        _:nrg_bal_c sdmx-dimension:timePeriod ?date .
        _:nrg_bal_c sdmx-attribute:unitMeasure unit:TJ .
        _:nrg_bal_c property:nrg_bal ?nrg_bal .
        _:nrg_bal_c sdmx-dimension:refArea ?geo .
        
        
           _:nrg_bal_c property:siec ?siec .

        FILTER (?siec in (siec:E7000, siec:R5300, siec:R5290, siec:R5220B, 
                          siec:R5210B, siec:R5110-5150_W6000RI, siec:O4680, 
                          siec:O4671XR5220B, siec:O4661XR5230B, siec:O4653, 
                          siec:O4652XR5210B, siec:O4651, siec:O4630, siec:G3000))

        _:nrg_bal_c sdmx-measure:obsValue ?obsValue .
      }
   FILTER (?geo in (geo:EU28, geo:LI, geo:NO, geo:CH, geo:TR, geo:IS))
   ?geo rdfs:label ?ugeo .
   FILTER (?nrg_bal in (nrg_bal:INTAVI, nrg_bal:FC_TRA_DAVI_E, 
                          nrg_bal:INTMARB, nrg_bal:FC_TRA_RAIL_E, 
                          nrg_bal:FC_TRA_ROAD_E, nrg_bal:FC_TRA_DNAVI_E)) 
   ?nrg_bal rdfs:label ?nrg_bal_label .
   } 
  }

}}
GROUP BY ?nrg_bal_label