Greenhouse gas emissions by EU Member State,1990,2000,2012

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX clrtap_nec_unfccc: <http://reference.eionet.europa.eu/clrtap_nec_unfccc/schema/>
PREFIX clrtap_geo: <http://reference.eionet.europa.eu/clrtap_nec_unfccc/country/>
PREFIX sector: <http://reference.eionet.europa.eu/clrtap_nec_unfccc/unfccc_crf_sector/>
PREFIX sdmx-measure: <http://purl.org/linked-data/sdmx/2009/measure#> 
PREFIX sdmx-dimension: <http://purl.org/linked-data/sdmx/2009/dimension#> 
PREFIX sdmx-attribute: <http://purl.org/linked-data/sdmx/2009/attribute#> 
PREFIX property: <http://rdfdata.eionet.europa.eu/eurostat/property#> 
PREFIX unit: <http://rdfdata.eionet.europa.eu/eurostat/dic/unit#>
PREFIX geo: <http://rdfdata.eionet.europa.eu/eurostat/dic/geo#>
PREFIX sex: <http://purl.org/linked-data/sdmx/2009/code#>
PREFIX age: <http://rdfdata.eionet.europa.eu/eurostat/dic/age#>

SELECT
?country_name
round(((sum(?end_year)/sum(?start_year))-1)*10000)/100.0 as ?difference

(round(sum(?start_year)/1000)) as ?1990
(round(sum(?mid_year)/1000)) as ?2000
(round(sum(?end_year)/1000)) as ?2012
(round(sum(?pop_start_year)/1000)) as ?pop_1990
(round(sum(?pop_mid_year)/1000)) as ?pop_2010
(round(sum(?pop_end_year)/1000)) as ?pop_2012

round(sum(?start_year)/sum(?pop_start_year)*1000) as ?pc_1990
round(sum(?mid_year)/sum(?pop_mid_year)*1000) as ?pc_2000
round(sum(?end_year)/sum(?pop_end_year)*1000) as ?pc_2012
round((((sum(?end_year)/sum(?pop_end_year))/(sum(?start_year)/sum(?pop_start_year)))-1)*10000)/100.0 as ?pc_difference

WHERE {
{
  GRAPH <http://r.eionet.europa.eu/rdfdumps/clrtap_nec_unfccc/unfccc_crf.rdf.gz> 
   {
      _:unfccc_crf clrtap_nec_unfccc:country_code ?country_uri . FILTER (?country_uri != clrtap_geo:GB and ?country_uri != clrtap_geo:GR)
      _:unfccc_crf clrtap_nec_unfccc:unit ?unit . FILTER (?unit = 'Gg CO2 equivalent')
      _:unfccc_crf clrtap_nec_unfccc:pollutant_name ?pollutant_name . 
      FILTER (?pollutant_name = 'All greenhouse gases - (CO2 equivalent)') 
      _:unfccc_crf clrtap_nec_unfccc:sector_code sector:NT_excl .
      {
        _:unfccc_crf clrtap_nec_unfccc:year ?year . FILTER (?year in ('1990'))
        _:unfccc_crf clrtap_nec_unfccc:emissions ?start_year .
      } UNION {
        _:unfccc_crf clrtap_nec_unfccc:year ?year . FILTER (?year in ('2000'))
        _:unfccc_crf clrtap_nec_unfccc:emissions ?mid_year .
      } UNION {
        _:unfccc_crf clrtap_nec_unfccc:year ?year . FILTER (?year in ('2012'))
        _:unfccc_crf clrtap_nec_unfccc:emissions ?end_year .
      }
   }
  } UNION {
  GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/demo_pjan.rdf.gz> 
   {
      _:demo_pjan sdmx-dimension:refArea ?country_uri . FILTER (?country_uri != geo:UK and ?country_uri != geo:EL)
      _:demo_pjan sdmx-dimension:age age:TOTAL . 
      _:demo_pjan sdmx-dimension:sex sex:sex-T . 
      {
        _:demo_pjan sdmx-dimension:timePeriod ?year . FILTER (year(?year) = 1990)
        _:demo_pjan sdmx-measure:obsValue ?pop_start_year .
      } UNION {
        _:demo_pjan sdmx-dimension:timePeriod ?year . FILTER (year(?year) = 2000)
        _:demo_pjan sdmx-measure:obsValue ?pop_mid_year .
      } UNION {
        _:demo_pjan sdmx-dimension:timePeriod ?year . FILTER (year(?year) = 2012)
        _:demo_pjan sdmx-measure:obsValue ?pop_end_year .
      }
   }
  }
  ?country_uri skos:notation ?country_code .
  ?country_uri_2 skos:notation ?country_code . 
  ?country_uri_2 skos:inScheme <http://rdfdata.eionet.europa.eu/eea/countries/> .
  ?country_uri_2 rdfs:label ?country_name .
 }
GROUP BY ?country_name
ORDER BY ?country_name