CO2 emission intensity of Public Electricity and Heat Production

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX sdmx-measure: <http://purl.org/linked-data/sdmx/2009/measure#> 
PREFIX sdmx-dimension: <http://purl.org/linked-data/sdmx/2009/dimension#> 
PREFIX sdmx-attribute: <http://purl.org/linked-data/sdmx/2009/attribute#> 
PREFIX skos: <http://www.w3.org/2004/02/skos/core#> 
PREFIX property: <http://rdfdata.eionet.europa.eu/eurostat/property#> 
PREFIX geo: <http://dd.eionet.europa.eu/vocabulary/eurostat/geo/>
PREFIX unit: <http://dd.eionet.europa.eu/vocabulary/eurostat/unit/>
PREFIX product: <http://dd.eionet.europa.eu/vocabulary/eurostat/product/>
PREFIX indic_nrg: <http://dd.eionet.europa.eu/vocabulary/eurostat/indic_nrg/>
PREFIX clrtap_nec_unfccc: <http://reference.eionet.europa.eu/clrtap_nec_unfccc/schema/>
PREFIX sector: <http://reference.eionet.europa.eu/clrtap_nec_unfccc/unfccc_crf_sector/>
PREFIX unfccc_geo: <http://reference.eionet.europa.eu/clrtap_nec_unfccc/country/>

SELECT DISTINCT
year(xsd:date(?date)) as ?date
?ugeo

round(sum(?unfccc_crf)/1000 /(sum(coalesce(?nrg_110a_5200_101121,0)) + sum(coalesce(?nrg_110a_6000_101121,0)) +sum(coalesce(?nrg_110a_5200_101109,0)))*100000000000/11630)/100.0 as ?index

WHERE {
  { 
  GRAPH <http://r.eionet.europa.eu/rdfdumps/clrtap_nec_unfccc/unfccc_crf.rdf.gz> 
    {
      SELECT 
        bif:either (?geo = unfccc_geo:EUA, geo:EU28, ?geo) as ?geo
        ?date
        ?unfccc_crf
      WHERE {
        _:unfccc_crf clrtap_nec_unfccc:country_code ?geo .
        _:unfccc_crf clrtap_nec_unfccc:year ?date .
        FILTER (?date != '1985-1987')
        {
          _:unfccc_crf clrtap_nec_unfccc:unit 'Gg' .
          _:unfccc_crf clrtap_nec_unfccc:pollutant_name 'CO2' .         
          _:unfccc_crf clrtap_nec_unfccc:sector_code sector:1.A.1.a . 
          _:unfccc_crf clrtap_nec_unfccc:emissions ?unfccc_crf .
        }
      }
    }
  } UNION {
  GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_110a.rdf.gz>
    {
      _:nrg_110a sdmx-dimension:timePeriod ?date .
      _:nrg_110a sdmx-attribute:unitMeasure unit:KTOE .
      _:nrg_110a sdmx-dimension:refArea ?geo .
      
      {
        _:nrg_110a property:indic_nrg indic_nrg:B_101121 .
        _:nrg_110a property:product product:5200 .
        _:nrg_110a sdmx-measure:obsValue ?nrg_110a_5200_101121 .
      } UNION {
        _:nrg_110a property:indic_nrg indic_nrg:B_101121 .
        _:nrg_110a property:product product:6000 .
        _:nrg_110a sdmx-measure:obsValue ?nrg_110a_6000_101121 .
      } UNION {
        _:nrg_110a property:indic_nrg indic_nrg:B_101109 .
        _:nrg_110a property:product product:5200 .
        _:nrg_110a sdmx-measure:obsValue ?nrg_110a_5200_101109 .
      }
     
    } 
  }
  ?geo rdfs:label ?ugeo .
}
GROUP BY xsd:date(?date) ?ugeo 
HAVING (sum(coalesce(?nrg_110a_5200_101121,0)) + sum(coalesce(?nrg_110a_6000_101121,0)) +sum(coalesce(?nrg_110a_5200_101109,0)) ) > 0 &&  sum(?unfccc_crf) > 0
ORDER BY xsd:date(?date) ?ugeo