next
previous
items

Data table via SPARQL

CO2-emission intensity from electricity generation

Data table via SPARQL Published 26 Jul 2021 Last modified 19 Jan 2022
30 min read
This is an old version, kept for reference only.

Go to latest version
Topics:

Download this dataset

Dataset preview

(Live Query)

date ugeo index
"1990"^^<http://www.w3.org/2001/XMLSchema#int> "Austria" "233"^^<http://www.w3.org/2001/XMLSchema#decimal>
"1990"^^<http://www.w3.org/2001/XMLSchema#int> "Belgium" "358"^^<http://www.w3.org/2001/XMLSchema#decimal>
"1990"^^<http://www.w3.org/2001/XMLSchema#int> "Bulgaria" "661"^^<http://www.w3.org/2001/XMLSchema#decimal>
"1990"^^<http://www.w3.org/2001/XMLSchema#int> "Croatia" "333"^^<http://www.w3.org/2001/XMLSchema#decimal>
"1990"^^<http://www.w3.org/2001/XMLSchema#int> "Cyprus" "852"^^<http://www.w3.org/2001/XMLSchema#decimal>
"1990"^^<http://www.w3.org/2001/XMLSchema#int> "Czechia" "727"^^<http://www.w3.org/2001/XMLSchema#decimal>
"1990"^^<http://www.w3.org/2001/XMLSchema#int> "Denmark" "686"^^<http://www.w3.org/2001/XMLSchema#decimal>
"1990"^^<http://www.w3.org/2001/XMLSchema#int> "EU-27" "501"^^<http://www.w3.org/2001/XMLSchema#decimal>
"1990"^^<http://www.w3.org/2001/XMLSchema#int> "EU-27 + UK" "524"^^<http://www.w3.org/2001/XMLSchema#decimal>
"1990"^^<http://www.w3.org/2001/XMLSchema#int> "Estonia" "853"^^<http://www.w3.org/2001/XMLSchema#decimal>

Received 990 rows in 0.025 seconds.


https://www.eea.europa.eu/data-and-maps/daviz/sds/co2-emission-intensity-from-electricity-generation-5/daviz.json

For system integrators

The following info can be used by a system developer / database administrator in order to retrieve this dataset programmatically over the web using a SPARQL client.

Are you new to Linked Data technology? visit http://linkeddata.org



http://semantic.eea.europa.eu/sparql

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX sdmx-measure: <http://purl.org/linked-data/sdmx/2009/measure#> 
PREFIX sdmx-dimension: <http://purl.org/linked-data/sdmx/2009/dimension#> 
PREFIX sdmx-attribute: <http://purl.org/linked-data/sdmx/2009/attribute#> 
PREFIX skos: <http://www.w3.org/2004/02/skos/core#> 
PREFIX property: <http://rdfdata.eionet.europa.eu/eurostat/property#> 
PREFIX geo: <http://dd.eionet.europa.eu/vocabulary/eurostat/geo/>
PREFIX unit: <http://dd.eionet.europa.eu/vocabulary/eurostat/unit/>
PREFIX product: <http://dd.eionet.europa.eu/vocabulary/eurostat/product/>
PREFIX clrtap_nec_unfccc: <http://reference.eionet.europa.eu/clrtap_nec_unfccc/schema/>
PREFIX sector: <http://reference.eionet.europa.eu/clrtap_nec_unfccc/unfccc_crf_sector/>
PREFIX unfccc_geo: <http://reference.eionet.europa.eu/clrtap_nec_unfccc/country/>
PREFIX common_countries: <http://dd.eionet.europa.eu/vocabulary/common/countries/>
PREFIX siec: <http://dd.eionet.europa.eu/vocabulary/eurostat/siec/>
PREFIX nrg_bal: <http://dd.eionet.europa.eu/vocabulary/eurostat/nrg_bal/>
PREFIX measure: <http://purl.org/linked-data/sdmx/2009/measure#>

SELECT
?date
?ugeo
?index

{
SELECT DISTINCT
year(?date) AS ?date
bif:either(?geo = geo:DE, 'Germany', bif:either(?geo = geo:EU27_2020, 'EU-27', bif:either(?geo = geo:EU28, 'EU-27 + UK', ?ugeo))) AS ?ugeo

SUM(?unfccc_crf)/1000.0 AS ?D19

( SUM(?TI_EHG_MAPE_E) + SUM(?TI_EHG_MAPCHP_E) + SUM(?TI_EHG_MAPH_E) ) AS ?D23

IF ( (xsd:double(SUM(?TI_EHG_MAPH_E)) = 0 || xsd:double(SUM(?GHP_MAPH))= 0), 0.9, (xsd:double(SUM(?GHP_MAPH)) / xsd:double(SUM(?TI_EHG_MAPH_E))) ) AS ?D24_den

( ( SUM(?TI_EHG_MAPE_E) + SUM(?TI_EHG_MAPCHP_E) + SUM(?TI_EHG_MAPH_E)) - ( ( SUM(?GHP_MAPCHP) + SUM(?GHP_MAPH) ) ) / ?D24_den ) AS ?D24

IF ( (xsd:double(SUM(?GHP_APH)) = 0 || xsd:double(SUM(?TI_EHG_APH_E))= 0), 0.9, (xsd:double(SUM(?GHP_APH)) / xsd:double(SUM(?TI_EHG_APH_E))) ) AS ?D61_den

( ( SUM(?TI_EHG_APE_E) + SUM(?TI_EHG_APCHP_E) + SUM(?TI_EHG_APH_E)) - ( ( SUM(?GHP_APCHP) + SUM(?GHP_APH) ) ) / ?D61_den ) AS ?D61


( ?D19 * ?D24 / ?D23 ) AS ?D15
( ?D15 * ?D61 / ?D24 ) AS ?D16
( ?D15 + ?D16 )  AS ?D14

( SUM(?GEP_MAPE) + SUM(?GEP_MAPCHP) + SUM(?GEP_APE) + SUM(?GEP_APCHP) ) / 86.0 AS ?D99

ROUND ( ?D14 / ?D99 * 1000.0 ) AS ?index

#DEBUG PURPOSES
#SUM(?TI_EHG_MAPE_E) AS ?TI_EHG_MAPE_E
#SUM(?TI_EHG_MAPCHP_E) AS ?TI_EHG_MAPCHP_E
#SUM(?TI_EHG_MAPH_E) AS ?TI_EHG_MAPH_E
#SUM(?GHP_MAPCHP) AS ?GHP_MAPCHP
#SUM(?GHP_MAPH) AS ?GHP_MAPH
#SUM(?TI_EHG_APE_E) AS ?TI_EHG_APE_E
#SUM(?TI_EHG_APCHP_E) AS ?TI_EHG_APCHP_E
#SUM(?TI_EHG_APH_E) AS ?TI_EHG_APH_E
#SUM(?GHP_APCHP) AS ?GHP_APCHP
#SUM(?GHP_APH) AS ?GHP_APH 

#SUM(?GEP_MAPE) AS ?GEP_MAPE
#SUM(?GEP_MAPCHP) AS ?GEP_MAPCHP
#SUM(?GEP_APE) AS ?GEP_APE
#SUM(?GEP_APCHP) AS ?GEP_APCHP

  WHERE {{

      {{
        SELECT
          xsd:date(?year) AS ?date
          URI(replace(replace(replace(replace(xsd:string(?country_code), 'http://reference.eionet.europa.eu/clrtap_nec_unfccc/country/', 'http://dd.eionet.europa.eu/vocabulary/eurostat/geo/'), 'EUX', 'EU27_2020'), 'GR', 'EL'), 'EUA', 'EU28')) AS ?geo
          ?unfccc_crf
        WHERE {
          GRAPH <http://r.eionet.europa.eu/rdfdumps/clrtap_nec_unfccc/unfccc_crf.rdf.gz> 
          {
            _:unfccc_crf clrtap_nec_unfccc:country_code ?country_code .
            _:unfccc_crf clrtap_nec_unfccc:year ?year .
            FILTER (?year != '1985-1987')
            {
              #_:unfccc_crf clrtap_nec_unfccc:unit 'Gg' .
              #_:unfccc_crf clrtap_nec_unfccc:pollutant_name 'CO2' .         
              _:unfccc_crf clrtap_nec_unfccc:pollutant_name 'All greenhouse gases - (CO2 equivalent)' .         
              _:unfccc_crf clrtap_nec_unfccc:sector_code sector:1.A.1.a . 
              _:unfccc_crf clrtap_nec_unfccc:emissions ?unfccc_crf .
            }
          }
          ?country_code skos:notation ?ugeo_unfccc .
        }
      }}

      } UNION {
      GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_bal_c_ktoe.rdf.gz>
        {
          _:nrg_bal_c sdmx-dimension:timePeriod ?date .
          _:nrg_bal_c sdmx-attribute:unitMeasure unit:KTOE .
          _:nrg_bal_c sdmx-dimension:refArea ?geo .

          {
          _:nrg_bal_c property:siec ?siec .
             FILTER (?siec IN 
                        (
                          siec:C0000X0350-0370, 
                          siec:O4000XBIO,
                          siec:G3000,
                          siec:C0350-0370, 
                          siec:P1000, 
                          siec:S2000, 
                          siec:W6100_6220
                        )
                    )
           {
              _:nrg_bal_c property:nrg_bal nrg_bal:TI_EHG_MAPE_E .
              _:nrg_bal_c measure:obsValue ?TI_EHG_MAPE_E . #SUM(D25:D31)
           } UNION {
              _:nrg_bal_c property:nrg_bal nrg_bal:TI_EHG_MAPCHP_E .
              _:nrg_bal_c measure:obsValue ?TI_EHG_MAPCHP_E . #SUM(D32:D38)
           } UNION {
              _:nrg_bal_c property:nrg_bal nrg_bal:TI_EHG_MAPH_E .
              _:nrg_bal_c measure:obsValue ?TI_EHG_MAPH_E . #SUM(D39:D45)
           } UNION {
              _:nrg_bal_c property:nrg_bal nrg_bal:GHP_MAPCHP .
              _:nrg_bal_c measure:obsValue ?GHP_MAPCHP . #SUM(D46:D52)
           } UNION {
              _:nrg_bal_c property:nrg_bal nrg_bal:GHP_MAPH .
              _:nrg_bal_c measure:obsValue ?GHP_MAPH . #SUM(D53:D59)
           } UNION {
              _:nrg_bal_c property:nrg_bal nrg_bal:TI_EHG_APE_E .
              _:nrg_bal_c measure:obsValue ?TI_EHG_APE_E . #SUM(D53:D59)
           } UNION {
              _:nrg_bal_c property:nrg_bal nrg_bal:TI_EHG_APCHP_E .
              _:nrg_bal_c measure:obsValue ?TI_EHG_APCHP_E . #SUM(D53:D59)
           } UNION {
              _:nrg_bal_c property:nrg_bal nrg_bal:TI_EHG_APH_E .
              _:nrg_bal_c measure:obsValue ?TI_EHG_APH_E  . #SUM(D53:D59)
           } UNION {
              _:nrg_bal_c property:nrg_bal nrg_bal:GHP_APCHP .
              _:nrg_bal_c measure:obsValue ?GHP_APCHP . #SUM(D53:D59)
           } UNION {
              _:nrg_bal_c property:nrg_bal nrg_bal:GHP_APH .
              _:nrg_bal_c measure:obsValue ?GHP_APH . #SUM(D53:D59)
           }
        } UNION {
          _:nrg_bal_c property:siec siec:TOTAL .
             #FILTER (?siec IN (siec:TOTAL))
          {
              _:nrg_bal_c property:nrg_bal nrg_bal:GEP_MAPE .
              _:nrg_bal_c measure:obsValue ?GEP_MAPE .
          } UNION {
              _:nrg_bal_c property:nrg_bal nrg_bal:GEP_MAPCHP .
              _:nrg_bal_c measure:obsValue ?GEP_MAPCHP  .
           } UNION {
              _:nrg_bal_c property:nrg_bal nrg_bal:GEP_APE .
              _:nrg_bal_c measure:obsValue ?GEP_APE . 
           } UNION {
              _:nrg_bal_c property:nrg_bal nrg_bal:GEP_APCHP .
              _:nrg_bal_c measure:obsValue ?GEP_APCHP . 
           }
        }
      }
    }
    ?geo rdfs:label ?ugeo .
    #FILTER (?geo IN (geo:ES))
    FILTER (?geo IN (geo:EU27_2020, geo:EU28, geo:BE, geo:BG,
                     geo:CZ,	geo:DK,	geo:DE,	geo:EE,
                     geo:IE,	geo:EL,	geo:ES,	geo:FR,	
                     geo:HR,	geo:IT,	geo:CY,	geo:LV,
                     geo:LT,	geo:LU,	geo:HU,	geo:MT,		
                     geo:NL,	geo:AT,	geo:PL,	geo:PT,	
                     geo:RO,	geo:SI,	geo:SK,	geo:FI,
                     geo:SE,	geo:UK, geo:IS,	geo:TR,
                     geo:NO))

    FILTER (xsd:integer(substr(xsd:string(?date), 1, 4)) >= 1990) 

}

GROUP BY ?date ?geo ?ugeo ?D99 ?D14 ?D15 ?D16 ?D23 ?D24 ?D24_den ?D61 ?D61_den ?D19
}
ORDER BY ?date ?ugeo


Permalinks

Geographic coverage

Temporal coverage

Topics

Topics:

Tags

Filed under:
Filed under: electricity generation
Document Actions