CO2-emission intensity from electricity generation

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX sdmx-measure: <http://purl.org/linked-data/sdmx/2009/measure#> 
PREFIX sdmx-dimension: <http://purl.org/linked-data/sdmx/2009/dimension#> 
PREFIX sdmx-attribute: <http://purl.org/linked-data/sdmx/2009/attribute#> 
PREFIX skos: <http://www.w3.org/2004/02/skos/core#> 
PREFIX property: <http://rdfdata.eionet.europa.eu/eurostat/property#> 
PREFIX geo: <http://dd.eionet.europa.eu/vocabulary/eurostat/geo/>
PREFIX unit: <http://dd.eionet.europa.eu/vocabulary/eurostat/unit/>
PREFIX product: <http://dd.eionet.europa.eu/vocabulary/eurostat/product/>
PREFIX clrtap_nec_unfccc: <http://reference.eionet.europa.eu/clrtap_nec_unfccc/schema/>
PREFIX sector: <http://reference.eionet.europa.eu/clrtap_nec_unfccc/unfccc_crf_sector/>
PREFIX unfccc_geo: <http://reference.eionet.europa.eu/clrtap_nec_unfccc/country/>
PREFIX common_countries: <http://dd.eionet.europa.eu/vocabulary/common/countries/>
PREFIX siec: <http://dd.eionet.europa.eu/vocabulary/eurostat/siec/>
PREFIX nrg_bal: <http://dd.eionet.europa.eu/vocabulary/eurostat/nrg_bal/>
PREFIX measure: <http://purl.org/linked-data/sdmx/2009/measure#>

SELECT DISTINCT
year(?date) AS ?date
bif:either(?geo = geo:DE, 'Germany', ?ugeo) AS ?ugeo

SUM(?unfccc_crf)/1000.0 AS ?D19
SUM(?ei_MAP) AS ?D22
(?D22 - (SUM(?dh_MAP)/0.9)) AS ?D23
?D19 * (?D23 / ?D22) AS ?D15
(SUM(?ei_AP) - (SUM(?dh_AP)/ 0.9)) AS ?D59 
?D15 * ?D59/ ?D23 AS ?D16
(?D15+?D16) aS ?D14

SUM(?GEP)/86 AS ?D97
ROUND(?D14 / ?D97 * 1000.0) AS ?index

#SUM(?ei_MAP) AS ?ei_MAP
#SUM(?ei_AP) AS ?ei_AP
#SUM(?dh_MAP) AS ?dh_MAP
#SUM(?dh_AP) AS ?dh_AP
#SUM(?GEP)/86 AS ?GEP
#SUM(?unfccc_crf) AS ?unfccc_crf
  WHERE {{

      {{
        SELECT
          xsd:date(?year) AS ?date
          URI(replace(replace(replace(replace(xsd:string(?country_code), 'http://reference.eionet.europa.eu/clrtap_nec_unfccc/country/', 'http://dd.eionet.europa.eu/vocabulary/eurostat/geo/'), 'EUX', 'EU27_2020'), 'GR', 'EL'), 'EUA', 'EU28')) AS ?geo
          ?unfccc_crf
        WHERE {
          GRAPH <http://r.eionet.europa.eu/rdfdumps/clrtap_nec_unfccc/unfccc_crf.rdf.gz> 
          {
            _:unfccc_crf clrtap_nec_unfccc:country_code ?country_code .
            _:unfccc_crf clrtap_nec_unfccc:year ?year .
            FILTER (?year != '1985-1987')
            {
              #_:unfccc_crf clrtap_nec_unfccc:unit 'Gg' .
              #_:unfccc_crf clrtap_nec_unfccc:pollutant_name 'CO2' .         
              _:unfccc_crf clrtap_nec_unfccc:pollutant_name 'All greenhouse gases - (CO2 equivalent)' .         
              _:unfccc_crf clrtap_nec_unfccc:sector_code sector:1.A.1.a . 
              _:unfccc_crf clrtap_nec_unfccc:emissions ?unfccc_crf .
            }
          }
          ?country_code skos:notation ?ugeo_unfccc .
        }
      }}

      } UNION {
      GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_bal_c_ktoe.rdf.gz>
        {
          _:nrg_bal_c sdmx-dimension:timePeriod ?date .
          _:nrg_bal_c sdmx-attribute:unitMeasure unit:KTOE .
          _:nrg_bal_c sdmx-dimension:refArea ?geo .

          {
          _:nrg_bal_c property:siec ?siec .
             FILTER (?siec IN (siec:C0000X0350-0370, siec:C0350-0370, 
                               siec:G3000, siec:O4000XBIO, 
                               siec:P1000, siec:S2000, 
                               siec:W6100_6220)
                    )
           {
              _:nrg_bal_c property:nrg_bal ?nrg_bal .
              FILTER (?nrg_bal IN (
                  nrg_bal:TI_EHG_MAPE_E, nrg_bal:TI_EHG_MAPCHP_E, nrg_bal:TI_EHG_MAPH_E
              ))
              _:nrg_bal_c measure:obsValue ?ei_MAP .
           } UNION {
              _:nrg_bal_c property:nrg_bal ?nrg_bal .
              FILTER (?nrg_bal IN (
                  nrg_bal:TI_EHG_APE_E, nrg_bal:TI_EHG_APCHP_E, nrg_bal:TI_EHG_APH_E
              ))
              _:nrg_bal_c measure:obsValue ?ei_AP .
           } UNION {
              _:nrg_bal_c property:nrg_bal ?nrg_bal .
              FILTER (?nrg_bal IN (
                  nrg_bal:GHP_MAPCHP, nrg_bal:GHP_MAPH
              ))
              _:nrg_bal_c measure:obsValue ?dh_MAP .
           } UNION {
              _:nrg_bal_c property:nrg_bal ?nrg_bal .
              FILTER (?nrg_bal IN (
                  nrg_bal:GHP_APCHP, nrg_bal:GHP_APH
              ))
              _:nrg_bal_c measure:obsValue ?dh_AP .
           }
        } UNION {
          _:nrg_bal_c property:siec ?siec .
             FILTER (?siec IN (siec:TOTAL))
          _:nrg_bal_c property:nrg_bal ?nrg_bal .
              FILTER (?nrg_bal IN (
                  nrg_bal:GEP_MAPE, nrg_bal:GEP_MAPCHP,
                  nrg_bal:GEP_APE, nrg_bal:GEP_APCHP
              ))
              _:nrg_bal_c measure:obsValue ?GEP .
        }
      }
    }
    ?geo rdfs:label ?ugeo .
    FILTER (?geo IN (geo:EU27_2020, geo:EU28, geo:BE, geo:BG,
                     geo:CZ,	geo:DK,	geo:DE,	geo:EE,
                     geo:IE,	geo:EL,	geo:ES,	geo:FR,	
                     geo:HR,	geo:IT,	geo:CY,	geo:LV,
                     geo:LT,	geo:LU,	geo:HU,	geo:MT,		
                     geo:NL,	geo:AT,	geo:PL,	geo:PT,	
                     geo:RO,	geo:SI,	geo:SK,	geo:FI,
                     geo:SE,	geo:UK, geo:IS,	geo:TR,
                     geo:NO))

    FILTER (xsd:integer(substr(xsd:string(?date), 1, 4)) >= 1990) 
}
ORDER BY ?date