Average annual growth rates for different fuels 2005-2017

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX sdmx-measure: <http://purl.org/linked-data/sdmx/2009/measure#> 
PREFIX sdmx-dimension: <http://purl.org/linked-data/sdmx/2009/dimension#>
PREFIX sdmx-attribute: <http://purl.org/linked-data/sdmx/2009/attribute#> 
PREFIX property: <http://rdfdata.eionet.europa.eu/eurostat/property#>
PREFIX siec: <http://dd.eionet.europa.eu/vocabulary/eurostat/siec/>
PREFIX nrg_bal: <http://dd.eionet.europa.eu/vocabulary/eurostat/nrg_bal/>
PREFIX geo: <http://dd.eionet.europa.eu/vocabulary/eurostat/geo/>
PREFIX unit: <http://dd.eionet.europa.eu/vocabulary/eurostat/unit/>

SELECT DISTINCT
?siec_label 
'2005-2017' as ?period
round(((bif:power((sum(?last_year)/sum(?first_year)),(1/12.0)))-1)*10000)/100.0 as ?value

{{

  SELECT DISTINCT
  ?siec
  ?siec_label
  bif:either (year(?date) = 2005, (?obsValue), 0) as ?first_year
  bif:either (year(?date) = 2017, (?obsValue), 0) as ?last_year
  {{
    SELECT DISTINCT
    ?date
    ?siec
    ?siec_label
    if(?siec = siec:TOTAL, round((sum(DISTINCT ?GIC) - sum(?FC_NE_total))/1000) , round((sum(DISTINCT ?GIC) - sum(coalesce(?FC_NE,0)))/1000)) as ?obsValue

    WHERE { 
      GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_bal_c.rdf.gz> {
        ?nrg_bal_c sdmx-dimension:refArea geo:EU28 .
        ?nrg_bal_c sdmx-attribute:unitMeasure unit:KTOE .
        ?nrg_bal_c sdmx-dimension:timePeriod ?date .
   
        {
          ?nrg_bal_c property:nrg_bal nrg_bal:GIC .
          ?nrg_bal_c property:siec ?siec .
          FILTER (?siec in (siec:C0000X0350-0370, siec:RA000, siec:O4000XBIO, 
                            siec:G3000, siec:N900H, siec:TOTAL))
          OPTIONAL { ?nrg_bal_c sdmx-measure:obsValue ?GIC } .
        } UNION {
          ?nrg_bal_c property:nrg_bal nrg_bal:FC_NE .
          ?nrg_bal_c property:siec ?siec .
          FILTER (?siec in (siec:C0000X0350-0370, siec:RA000, siec:O4000XBIO, 
                            siec:G3000, siec:N900H))
          OPTIONAL { ?nrg_bal_c sdmx-measure:obsValue ?FC_NE } .
        }

        ?nrg_bal_c_total sdmx-dimension:refArea geo:EU28 .
        ?nrg_bal_c_total sdmx-attribute:unitMeasure unit:KTOE .
        ?nrg_bal_c_total sdmx-dimension:timePeriod ?date .
        ?nrg_bal_c_total property:nrg_bal nrg_bal:FC_NE .
        ?nrg_bal_c_total property:siec siec:TOTAL .
        ?nrg_bal_c_total sdmx-measure:obsValue ?FC_NE_total .
        FILTER (year(?date) in (2005, 2017))
      }
    ?siec rdfs:label ?siec_label .
    }
  }}
}}
ORDER BY ?siec_label ?date