Growth in transport energy consumption, 1990-2017

PREFIX sdmx-measure: <http://purl.org/linked-data/sdmx/2009/measure#> 
PREFIX sdmx-dimension: <http://purl.org/linked-data/sdmx/2009/dimension#>
PREFIX sdmx-attribute: <http://purl.org/linked-data/sdmx/2009/attribute#> 
PREFIX skos: <http://www.w3.org/2004/02/skos/core#> 
PREFIX property: <http://rdfdata.eionet.europa.eu/eurostat/property#> 
PREFIX unit: <http://dd.eionet.europa.eu/vocabulary/eurostat/unit/>
PREFIX siec: <http://dd.eionet.europa.eu/vocabulary/eurostat/siec/>
PREFIX nrg_bal: <http://dd.eionet.europa.eu/vocabulary/eurostat/nrg_bal/>
PREFIX geo: <http://dd.eionet.europa.eu/vocabulary/eurostat/geo/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX estat_countries: <http://rdfdata.eionet.europa.eu/eea/countries/>

SELECT
'' as ?dummy
bif:either(?memberOf_label = 'NMS13', 'EU-13', 
bif:either(?memberOf_label = 'EU15', 'EU-15', 
bif:either(?memberOf_label = 'EEA33', 'EEA-33', 
?memberOf_label))) as ?memberOf_label
round((( SUM(?last_year)-SUM(?first_year) ) / SUM(?first_year) )*1000)/10.0 as ?index
{{
  SELECT DISTINCT
  ?date
  ?memberOf_label
  bif:either(year(?date) = 1990, (sum(?total)-sum(?C0000X03500370)), 0) as ?first_year
  bif:either(year(?date) = 2017, (sum(?total)-sum(?C0000X03500370)), 0) as ?last_year

  WHERE {
  {
    GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_bal_s.rdf.gz>
      {
        _:nrg_bal_s sdmx-dimension:timePeriod ?date . 
        FILTER (year(?date) in (1990, 2017))
        _:nrg_bal_s sdmx-attribute:unitMeasure unit:TJ . 
        _:nrg_bal_s property:nrg_bal ?nrg_bal .
        FILTER (?nrg_bal in (nrg_bal:INTMARB, nrg_bal:FC_TRA_RAIL_E, 
                               nrg_bal:FC_TRA_ROAD_E, nrg_bal:FC_TRA_DNAVI_E, 
                               nrg_bal:INTAVI, nrg_bal:FC_TRA_DAVI_E))
        _:nrg_bal_s sdmx-dimension:refArea ?geo .
        {
          _:nrg_bal_s property:siec siec:TOTAL .
          _:nrg_bal_s sdmx-measure:obsValue ?total .
        } UNION {
          _:nrg_bal_s property:siec siec:C0000X0350-0370 .
          _:nrg_bal_s sdmx-measure:obsValue ?C0000X03500370 .
        }
      }
    } 
    ?geo skos:notation ?ugeo .
    ?eeageo owl:sameAs ?geo .
    ?eeageo skos:inScheme estat_countries: .
    ?memberOf skos:member ?eeageo .
    FILTER (?memberOf IN (estat_countries:EEA33, estat_countries:NMS13, estat_countries:EU15)) .
    ?memberOf skos:notation ?memberOf_label
  }
GROUP BY ?memberOf ?memberOf_label ?date

}}
GROUP BY ?memberOf_label
ORDER BY ?memberOf_label