Average efficiency of the electric sector per country (without pumped hydro)

Data table via SPARQL Published 14 Nov 2017 Last modified 08 May 2018
30 min read
This is an old version, kept for reference only.

Go to latest version
Topics: ,

Download this dataset

Dataset preview

(Live Query)

date ugeo efficiency
"1990"^^<http://www.w3.org/2001/XMLSchema#int> "Albania" "69.8"^^<http://www.w3.org/2001/XMLSchema#decimal>
"1991"^^<http://www.w3.org/2001/XMLSchema#int> "Albania" "81.1"^^<http://www.w3.org/2001/XMLSchema#decimal>
"1992"^^<http://www.w3.org/2001/XMLSchema#int> "Albania" "87.1"^^<http://www.w3.org/2001/XMLSchema#decimal>
"1993"^^<http://www.w3.org/2001/XMLSchema#int> "Albania" "79.2"^^<http://www.w3.org/2001/XMLSchema#decimal>
"1994"^^<http://www.w3.org/2001/XMLSchema#int> "Albania" "76.2"^^<http://www.w3.org/2001/XMLSchema#decimal>
"1995"^^<http://www.w3.org/2001/XMLSchema#int> "Albania" "86.8"^^<http://www.w3.org/2001/XMLSchema#decimal>
"1996"^^<http://www.w3.org/2001/XMLSchema#int> "Albania" "92"^^<http://www.w3.org/2001/XMLSchema#decimal>
"1997"^^<http://www.w3.org/2001/XMLSchema#int> "Albania" "91"^^<http://www.w3.org/2001/XMLSchema#decimal>
"1998"^^<http://www.w3.org/2001/XMLSchema#int> "Albania" "91"^^<http://www.w3.org/2001/XMLSchema#decimal>
"1999"^^<http://www.w3.org/2001/XMLSchema#int> "Albania" "92.8"^^<http://www.w3.org/2001/XMLSchema#decimal>

Received 1038 rows in 0.090 seconds.


https://www.eea.europa.eu/data-and-maps/daviz/sds/average-efficiency-of-the-electric-4/daviz.json

For system integrators

The following info can be used by a system developer / database administrator in order to retrieve this dataset programmatically over the web using a SPARQL client.

Are you new to Linked Data technology? visit http://linkeddata.org



http://semantic.eea.europa.eu/sparql

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX sdmx-measure: <http://purl.org/linked-data/sdmx/2009/measure#> 
PREFIX sdmx-dimension: <http://purl.org/linked-data/sdmx/2009/dimension#> 
PREFIX sdmx-attribute: <http://purl.org/linked-data/sdmx/2009/attribute#> 
PREFIX skos: <http://www.w3.org/2004/02/skos/core#> 
PREFIX property: <http://rdfdata.eionet.europa.eu/eurostat/property#> 
PREFIX geo: <http://dd.eionet.europa.eu/vocabulary/eurostat/geo/>
PREFIX indic_nrg: <http://dd.eionet.europa.eu/vocabulary/eurostat/indic_nrg/>
PREFIX product: <http://dd.eionet.europa.eu/vocabulary/eurostat/product/>
PREFIX unit: <http://dd.eionet.europa.eu/vocabulary/eurostat/unit/>

SELECT 
?date
?ugeo 

round(((?el_energy_oil + ?el_energy_coal_lignite + ?el_energy_natural_gas_and_derived_gas + ?el_energy_nuclear + ?el_energy_hydro - ?el_energy_pumped_hydro + ?el_energy_geothermal + ?el_energy_wind + ?el_energy_biomass + ?el_energy_solar + ?el_energy_other_fuels ) / ?energy)*1000)/10.0 as ?efficiency

#(?el_energy_oil + ?el_energy_coal_lignite + ?el_energy_natural_gas_and_derived_gas + ?el_energy_nuclear + ?el_energy_hydro - ?el_energy_pumped_hydro + ?el_energy_geothermal + ?el_energy_wind + ?el_energy_biomass + ?el_energy_solar + ?el_energy_other_fuels ) as ?nominator
#?energy as ?denominator
{

SELECT DISTINCT
year(?date) as ?date
bif:either(?geo = geo:DE, 'Germany', ?ugeo) as ?ugeo 

(sum(?total_el_energy) - (sum(?el_energy_oil) + sum(?el_energy_coal_lignite) + sum(?el_energy_natural_gas_and_derived_gas) + sum(?el_energy_nuclear) + sum(?el_energy_renewable)))*86/1000 as ?el_energy_other_fuels
sum(?el_energy_oil)*86/1000 as ?el_energy_oil
sum(?el_energy_coal_lignite)*86/1000 as ?el_energy_coal_lignite
sum(?el_energy_natural_gas_and_derived_gas)*86/1000 as 
?el_energy_natural_gas_and_derived_gas
sum(?el_energy_nuclear)*86/1000 as ?el_energy_nuclear
(sum(?el_energy_renewable) - ( sum(?el_energy_hydro) + sum(?el_energy_geothermal) + sum(?el_energy_wind) +sum(?el_energy_solar) ))*86/1000 as ?el_energy_biomass
sum(?el_energy_hydro)*86/1000 as ?el_energy_hydro
sum(?el_energy_pumped_hydro)*86/1000 as ?el_energy_pumped_hydro
sum(?el_energy_geothermal)*86/1000 as ?el_energy_geothermal
sum(?el_energy_wind)*86/1000 as ?el_energy_wind
sum(?el_energy_solar)*86/1000 as ?el_energy_solar
sum(?el_energy_renewable)*86/1000 as ?el_energy_renewable
sum(?energy) as ?energy
WHERE {
{  
  GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_100a.rdf.gz> 
  { 
    _:nrg_100a sdmx-dimension:timePeriod ?date . 
    _:nrg_100a sdmx-attribute:unitMeasure unit:KTOE .
    _:nrg_100a sdmx-dimension:refArea ?geo .
    {
      _:nrg_100a property:product ?product . 
      FILTER (?product in (product:2000, product:3000, product:4000, product:5500))
      _:nrg_100a property:indic_nrg indic_nrg:B_101001 .
    } UNION {
      _:nrg_100a property:product product:5100 .
      _:nrg_100a property:indic_nrg indic_nrg:B_100100 .
    } 
    _:nrg_100a sdmx-measure:obsValue ?energy .
  }
  } UNION {
  GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_107a.rdf.gz> 
    { 
     _:nrg_107a sdmx-dimension:timePeriod ?date .
     _:nrg_107a sdmx-attribute:unitMeasure unit:KTOE .
     _:nrg_107a sdmx-dimension:refArea ?geo .
     _:nrg_107a property:product ?product . 
     FILTER (?product in (product:5510, product:5520))
     _:nrg_107a property:indic_nrg indic_nrg:B_100100 .
     _:nrg_107a sdmx-measure:obsValue ?energy .
   } 
 } UNION {
  GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_105a.rdf.gz> 
    { 
     _:nrg_105a sdmx-dimension:timePeriod ?date .
     _:nrg_105a sdmx-attribute:unitMeasure unit:GWH .
     _:nrg_105a sdmx-dimension:refArea ?geo .
     _:nrg_105a property:product product:6000 .
     { 
       _:nrg_105a property:indic_nrg ?indic_nrg . 
       FILTER (?indic_nrg in (
indic_nrg:22_108701, indic_nrg:22_108702, indic_nrg:22_108703, indic_nrg:22_108704, 
indic_nrg:22_108711, indic_nrg:22_108712, indic_nrg:22_108713, indic_nrg:22_108714, 
indic_nrg:22_108721, indic_nrg:22_108722, indic_nrg:22_108723, indic_nrg:22_108724, 
indic_nrg:22_108731, indic_nrg:22_108732, indic_nrg:22_108733, indic_nrg:22_108734, 
indic_nrg:22_108741, indic_nrg:22_108742, indic_nrg:22_108743, indic_nrg:22_108744, 
indic_nrg:22_108751, indic_nrg:22_108752, indic_nrg:22_108753, indic_nrg:22_108754, 
indic_nrg:22_108761, indic_nrg:22_108762, indic_nrg:22_108763, indic_nrg:22_108764, 
indic_nrg:22_108771, indic_nrg:22_108772, indic_nrg:22_108773, indic_nrg:22_108774, 
indic_nrg:22_108781, indic_nrg:22_108782, indic_nrg:22_108783, indic_nrg:22_108784, 
indic_nrg:22_108791, indic_nrg:22_108792, indic_nrg:22_108793, indic_nrg:22_108794, 
indic_nrg:22_108801, indic_nrg:22_108802, indic_nrg:22_108803, indic_nrg:22_108804, 
indic_nrg:22_108811, indic_nrg:22_108812, indic_nrg:22_108813, indic_nrg:22_108814))
       _:nrg_105a sdmx-measure:obsValue ?el_energy_oil .
     } UNION {
       _:nrg_105a property:indic_nrg ?indic_nrg . 
       FILTER (?indic_nrg in (
indic_nrg:22_108501, indic_nrg:22_108502, indic_nrg:22_108503, indic_nrg:22_108504, 
indic_nrg:22_108511, indic_nrg:22_108512, indic_nrg:22_108513, indic_nrg:22_108514, 
indic_nrg:22_108521, indic_nrg:22_108522, indic_nrg:22_108523, indic_nrg:22_108524, 
indic_nrg:22_108531, indic_nrg:22_108532, indic_nrg:22_108533, indic_nrg:22_108534, 
indic_nrg:22_108541, indic_nrg:22_108542, indic_nrg:22_108543, indic_nrg:22_108544, 
indic_nrg:22_108551, indic_nrg:22_108552, indic_nrg:22_108553, indic_nrg:22_108554, 
indic_nrg:22_108561, indic_nrg:22_108562, indic_nrg:22_108563, indic_nrg:22_108564, 
indic_nrg:22_108571, indic_nrg:22_108572, indic_nrg:22_108573, indic_nrg:22_108574, 
indic_nrg:22_108581, indic_nrg:22_108582, indic_nrg:22_108583, indic_nrg:22_108584, 
indic_nrg:22_108591, indic_nrg:22_108592, indic_nrg:22_108593, indic_nrg:22_108594, 
indic_nrg:22_108601, indic_nrg:22_108602, indic_nrg:22_108603, indic_nrg:22_108604))
       _:nrg_105a sdmx-measure:obsValue ?el_energy_coal_lignite .
     } UNION {
       _:nrg_105a property:indic_nrg ?indic_nrg . 
       FILTER (?indic_nrg in (
indic_nrg:22_108891, indic_nrg:22_108892, indic_nrg:22_108893, indic_nrg:22_108894, 
indic_nrg:22_108611, indic_nrg:22_108612, indic_nrg:22_108613, indic_nrg:22_108614, 
indic_nrg:22_108621, indic_nrg:22_108622, indic_nrg:22_108623, indic_nrg:22_108624, 
indic_nrg:22_108631, indic_nrg:22_108632, indic_nrg:22_108633, indic_nrg:22_108634, 
indic_nrg:22_108641, indic_nrg:22_108642, indic_nrg:22_108643, indic_nrg:22_108644)) 
       _:nrg_105a sdmx-measure:obsValue ?el_energy_natural_gas_and_derived_gas .
     } UNION {
       _:nrg_105a property:indic_nrg ?indic_nrg . 
       FILTER (?indic_nrg in (
indic_nrg:15_107030, indic_nrg:15_107031, indic_nrg:15_107032, indic_nrg:15_107033)) 
       _:nrg_105a sdmx-measure:obsValue ?el_energy_nuclear .
     } UNION {
       _:nrg_105a property:indic_nrg ?indic_nrg . 
       FILTER (?indic_nrg in (
indic_nrg:14_1070421, indic_nrg:14_1070422, indic_nrg:14_1070431, indic_nrg:14_1070432, indic_nrg:15_107034, indic_nrg:15_107035, indic_nrg:15_107046, indic_nrg:15_107047,
indic_nrg:22_108911, indic_nrg:22_108912, indic_nrg:22_108913, indic_nrg:22_108914, 
indic_nrg:22_108931, indic_nrg:22_108932, indic_nrg:22_108933, indic_nrg:22_108934,
indic_nrg:15_107038, indic_nrg:15_107039, indic_nrg:15_107040, indic_nrg:15_107041,
indic_nrg:22_108941, indic_nrg:22_108942, indic_nrg:22_108943, indic_nrg:22_108944, 
indic_nrg:22_108951, indic_nrg:22_108952, indic_nrg:22_108953, indic_nrg:22_108954, 
indic_nrg:22_108971, indic_nrg:22_108972, indic_nrg:22_108973, indic_nrg:22_108974, 
indic_nrg:15_107045, indic_nrg:15_107045))
       _:nrg_105a sdmx-measure:obsValue ?el_energy_renewable .
     } UNION {
       _:nrg_105a property:indic_nrg ?indic_nrg . 
       FILTER (?indic_nrg in (
indic_nrg:15_107038, indic_nrg:15_107039, indic_nrg:15_107040, indic_nrg:15_107041))
       _:nrg_105a sdmx-measure:obsValue ?el_energy_geothermal .
     } UNION {
       _:nrg_105a property:indic_nrg ?indic_nrg . 
       FILTER (?indic_nrg in (
indic_nrg:15_107034, indic_nrg:15_107035))
       _:nrg_105a sdmx-measure:obsValue ?el_energy_hydro .
     } UNION {
       _:nrg_105a property:indic_nrg ?indic_nrg . 
       FILTER (?indic_nrg in (
indic_nrg:15_107036, indic_nrg:15_107037))
       _:nrg_105a sdmx-measure:obsValue ?el_energy_pumped_hydro .
     } UNION {
       _:nrg_105a property:indic_nrg ?indic_nrg . 
       FILTER (?indic_nrg in (
indic_nrg:15_107046, indic_nrg:15_107047))
       _:nrg_105a sdmx-measure:obsValue ?el_energy_wind .
     } UNION {
       _:nrg_105a property:indic_nrg ?indic_nrg . 
       FILTER (?indic_nrg in (
indic_nrg:14_1070421, indic_nrg:14_1070422, indic_nrg:14_1070431, indic_nrg:14_1070432))
       _:nrg_105a sdmx-measure:obsValue ?el_energy_solar .
     } UNION {
       _:nrg_105a property:indic_nrg indic_nrg:17_107000 .
       _:nrg_105a sdmx-measure:obsValue ?total_el_energy .
     }
   } 
  }
?geo rdfs:label ?ugeo .
#FILTER (year(?date) = 2015)
#FILTER (?geo = geo:LU)

}

GROUP BY year(?date) ?ugeo ?geo
HAVING sum(?energy) > 0

}

ORDER BY ?ugeo ?date


Related content

Temporal coverage

Document Actions
Filed under: