Final energy intensity of agriculture, forestry and fishing sectors (2005=100), EU28

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX sdmx-measure: <http://purl.org/linked-data/sdmx/2009/measure#> 
PREFIX sdmx-dimension: <http://purl.org/linked-data/sdmx/2009/dimension#> 
PREFIX sdmx-attribute: <http://purl.org/linked-data/sdmx/2009/attribute#> 
PREFIX skos: <http://www.w3.org/2004/02/skos/core#> 
PREFIX property: <http://rdfdata.eionet.europa.eu/eurostat/property#> 
PREFIX geo: <http://dd.eionet.europa.eu/vocabulary/eurostat/geo/>
PREFIX unit: <http://dd.eionet.europa.eu/vocabulary/eurostat/unit/>
PREFIX siec: <http://dd.eionet.europa.eu/vocabulary/eurostat/siec/>
PREFIX nrg_bal: <http://dd.eionet.europa.eu/vocabulary/eurostat/nrg_bal/>
PREFIX na_item: <http://dd.eionet.europa.eu/vocabulary/eurostat/na_item/>
PREFIX nace_r2: <http://dd.eionet.europa.eu/vocabulary/eurostat/nace_r2/>

SELECT DISTINCT
year(?date) as ?date
'Agriculture, forestry and fishing' as ?sector
round(( ( sum(?nrg_bal_c)/ sum(?nama_10_a64)  ) / ( sum(?nrg_bal_c_idx)/ sum(?nama_10_a64_idx) ) )*1000)/10.0 as ?index
sum(?nrg_bal_c) as ?nrg_bal_c
sum(?nama_10_a64) as ?nama_10_a64
#sum(?nrg_bal_c_idx) as ?nrg_bal_c_idx
#sum(?nama_10_a64_idx) as ?nama_10_a64_idx

WHERE 
  {{  
  GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_bal_c.rdf.gz>
    {
      _:nrg_bal_c sdmx-dimension:timePeriod ?date .
      _:nrg_bal_c sdmx-attribute:unitMeasure unit:KTOE .
      _:nrg_bal_c sdmx-dimension:refArea geo:EU28 .
      _:nrg_bal_c property:siec siec:TOTAL .
      _:nrg_bal_c property:nrg_bal ?nrg_bal   .
      _:nrg_bal_c sdmx-measure:obsValue ?nrg_bal_c .

      _:nrg_bal_c_idx sdmx-dimension:timePeriod ?date_idx .
      _:nrg_bal_c_idx sdmx-attribute:unitMeasure unit:KTOE .
      _:nrg_bal_c_idx sdmx-dimension:refArea geo:EU28 .
      _:nrg_bal_c_idx property:siec siec:TOTAL .
      _:nrg_bal_c_idx property:nrg_bal ?nrg_bal .
      _:nrg_bal_c_idx sdmx-measure:obsValue ?nrg_bal_c_idx .

      FILTER (?nrg_bal in (nrg_bal:FC_OTH_AF_E, nrg_bal:FC_OTH_FISH_E))
     }
  } UNION {
  GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nama_10_a64.rdf.gz> 
    {
      _:nama_10_a64 sdmx-dimension:timePeriod ?date . 
      _:nama_10_a64 property:na_item na_item:B1G . 
      _:nama_10_a64 sdmx-dimension:refArea geo:EU28 . 
      _:nama_10_a64 property:nace_r2 nace_r2:A . 
      _:nama_10_a64 sdmx-attribute:unitMeasure unit:CLV10_MEUR . 
      _:nama_10_a64 sdmx-measure:obsValue ?nama_10_a64 .

      _:nama_10_a64_idx sdmx-dimension:timePeriod ?date_idx . 
      _:nama_10_a64_idx property:na_item na_item:B1G . 
      _:nama_10_a64_idx sdmx-dimension:refArea geo:EU28 . 
      _:nama_10_a64_idx property:nace_r2 nace_r2:A . 
      _:nama_10_a64_idx sdmx-attribute:unitMeasure unit:CLV10_MEUR . 
      _:nama_10_a64_idx sdmx-measure:obsValue ?nama_10_a64_idx .
    } 
  }
  FILTER (year(?date) >= 2005)
  FILTER (year(?date_idx) = 2005)
} 

GROUP BY year(?date)
ORDER BY ?date