Eionet deliveries 2011

PREFIX rdfns: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rod: <http://rod.eionet.europa.eu/schema.rdf#>
PREFIX rdfsh: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX dc: <http://purl.org/dc/terms/>
PREFIX cr: <http://cr.eionet.europa.eu/ontologies/contreg.rdf#>
PREFIX ns: <http://www.w3.org/ns/dcat#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX contreg: <http://cr.eionet.europa.eu/ontologies/contreg.rdf#>

SELECT DISTINCT
md5(sql:GROUP_CONCAT(?subj, ?fileUri )) as ?_id
?subj as ?envelopeUri 
?obligationUri 
?obligationTitle 
?instrumentUri 
?instrumentTitle
?iso2 
?country 
?envelopeTitle 
?envelopeReporter
?firstSeen
?released 
?feedbackUri 
?feedbackTitle 
?FeedbackStatus 
?fileUri 
?filename 
xsd:double(?filebyteSize)/1000.0 as ?fileKbSize
?fileMediaType 

WHERE
{{

  SELECT DISTINCT 
    *
  WHERE
    {
      ?subj a rod:Delivery .
      ?subj rod:locality ?locality .
      ?subj rod:obligation ?obligationUri .
      ?subj contreg:firstSeen ?firstSeen .
      ?subj rod:released ?released .
      ?subj dc:title ?envelopeTitle .
      ?subj dc:creator ?envelopeReporter .
      ?subj rod:hasFile ?fileUri.

      ?fileUri rdfsh:label ?filename .
      ?fileUri ns:byteSize ?filebyteSize .
      ?fileUri cr:mediaType ?fileMediaType .

      ?locality rod:localityName ?country .
      ?locality skos:notation ?iso2 .

      ?obligationUri dc:title ?obligationTitle .
      ?obligationUri rod:instrument ?instrumentUri .

      ?instrumentUri rdfs:label ?instrumentTitle .

      OPTIONAL { 
        ?subj cr:hasFeedback ?feedbackUri .
        ?feedbackUri dc:title ?feedbackTitle .
        ?feedbackUri cr:feedbackStatus ?FeedbackStatus .
        ?feedbackUri cr:feedbackFor ?fileUri .
       }
     FILTER NOT EXISTS {?feedbackUri cr:feedbackFor ?fileUri}
     }
} UNION {

  SELECT DISTINCT 
    *
  WHERE
    {
      ?subj a rod:Delivery .
      ?subj rod:locality ?locality .
      ?subj rod:obligation ?obligationUri .
      ?subj contreg:firstSeen ?firstSeen .
      ?subj rod:released ?released .       
      ?subj dc:title ?envelopeTitle .
      ?subj dc:creator ?envelopeReporter .

      ?locality rod:localityName ?country .
      ?locality skos:notation ?iso2 .
      ?obligationUri dc:title ?obligationTitle .
      ?obligationUri rod:instrument ?instrumentUri .

      ?instrumentUri rdfs:label ?instrumentTitle .
    
      ?subj cr:hasFeedback ?feedbackUri .

      ?feedbackUri dc:title ?feedbackTitle .
      ?feedbackUri cr:feedbackStatus ?FeedbackStatus .

      OPTIONAL { 
        ?feedbackUri cr:feedbackFor ?fileUri .
        ?fileUri rdfsh:label ?filename .
        ?fileUri ns:byteSize ?filebyteSize .
        ?fileUri cr:mediaType ?fileMediaType .
      }
    }
  }
FILTER (year(?released) in (2011))
}