Data and reporting obligations

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX dcterms: <http://purl.org/dc/terms/> 
PREFIX rdf-syntax: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX Specification: <http://www.eea.europa.eu/portal_types/Specification#>
PREFIX Assessment: <http://www.eea.europa.eu/portal_types/Assessment#>
PREFIX AssessmentPart: <http://www.eea.europa.eu/portal_types/AssessmentPart#>
PREFIX wgs84_pos: <http://www.w3.org/2003/01/geo/wgs84_pos#>
PREFIX EEAFigure: <http://www.eea.europa.eu/portal_types/EEAFigure#>
PREFIX GISApplication: <http://www.eea.europa.eu/portal_types/GIS%20Application#>
PREFIX Dashboard: <http://www.eea.europa.eu/portal_types/Dashboard#>
PREFIX output: <http://rdfdata.eionet.europa.eu/amp/ontology/Output>
PREFIX PolicyQuestion: <http://www.eea.europa.eu/portal_types/PolicyQuestion#>
PREFIX DavizVisualization: <http://www.eea.europa.eu/portal_types/DavizVisualization#>
PREFIX schemaorg: <http://schema.org/>
PREFIX ExternalDataSpec: <http://www.eea.europa.eu/portal_types/ExternalDataSpec#>
PREFIX Data: <http://www.eea.europa.eu/portal_types/Data#>
PREFIX portal_types: <http://www.eea.europa.eu/portal_types#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX countrygroups: <http://rdfdata.eionet.europa.eu/countrygroups/schema/>
PREFIX Organisation: <http://www.eea.europa.eu/portal_types/Organisation#>
PREFIX Obligations: <http://www.eea.europa.eu/portal_types/Obligations#>
PREFIX rodschema: <http://rod.eionet.europa.eu/schema.rdf#>

SELECT DISTINCT
?dataUri
?data
bif:either(!bound(?isReplacedBy), 1, 0) as ?latest
?dataTitle
?dataProviderUri
?dataProvider
?dataProductID
IRI(bif:concat('http://www.eea.europa.eu/ds_resolveuid/', ?dataProductID)) as ?dataLatest 
Min(xsd:integer(COALESCE(?temporalCoverage,0))) as ?temporalCoverageMin
Max(xsd:integer(COALESCE(?temporalCoverage,0))) as ?temporalCoverageMax
(Max(xsd:integer(COALESCE(?temporalCoverage,0))) - Min(xsd:integer(COALESCE(?temporalCoverage,0)))+1) as ?temporalCoverage

#?dataManagementPlan
bif:either(strlen(?dataManagementPlan) > 4, bif:either(bound(?dataManagementPlan), iri(bif:concat('http://applications/managementplan/ProjectPlan.aspx?year=', bif:left(?dataManagementPlan, 4 ), '&code=', bif:right(?dataManagementPlan, 5 ))), ''),'') as ?dataManagementPlanUri
?obligationsUri
?obligations
COALESCE(?isEEACore,0) as ?isEEACore
COALESCE(?isTerminated,0) as ?isTerminated
?verifiedBy as ?responsible
COALESCE(?reportingFrequencyMonths,0) as ?reportingFrequencyMonths
xsd:dateTime(?dataIssued) as ?dataIssued
?groups
COALESCE(?spatialcount,0) as ?spatialcount

WHERE {
  graph ?graph { ?dataUri rdf-syntax:type Data:Data } .
  FILTER (str(?graph) = concat(str(?dataUri), '/@@rdf') )
  ?dataUri rdfs:label ?data .
  ?dataUri dcterms:title ?dataTitle .
  ?dataUri schemaorg:productID ?dataProductID .

  OPTIONAL { ?dataUri dcterms:isReplacedBy ?isReplacedBy } .
  ?dataUri dcterms:issued ?dataIssued .
  OPTIONAL { ?dataUri Data:temporalCoverage ?temporalCoverage } .
  OPTIONAL { ?dataUri Data:eeaManagementPlan ?dataManagementPlan } .

  OPTIONAL { ?dataUri Obligations:Obligations ?obligationsUri } .
  OPTIONAL { ?obligationsUri dcterms:title ?obligations } .
  OPTIONAL { ?obligationsUri skos:notation ?obligationsCode } .
  OPTIONAL { ?obligationsUri rodschema:verifiedBy ?verifiedBy } .
  OPTIONAL { ?obligationsUri rodschema:isEEACore ?isEEACore } .
  OPTIONAL { ?obligationsUri rodschema:reportingFrequencyMonths ?reportingFrequencyMonths } .
  OPTIONAL { ?obligationsUri rodschema:isTerminated ?isTerminated } .

  ?dataUri portal_types:dataProvider ?dataProviderUri .
  OPTIONAL { ?dataProviderUri dcterms:title ?dataProvider} .
  ?dataProviderUri Organisation:organisationUrl ?organisationUrl .
  ?dataUri Data:dataOwner ?dataOwner .
  FILTER (?dataOwner = str(?organisationUrl))
  
  OPTIONAL { SELECT DISTINCT
      ?dataUri 
      sql:GROUP_CONCAT(?group,', ') as ?groups
      ?spatialcount
      ?type
    {{
      SELECT DISTINCT 
        *
        WHERE {
        { 
        GRAPH <http://r.eionet.europa.eu/rdfdumps/indicators/countrygroups.rdf.gz> 
          {
            _:a countrygroups:itemuri ?dataUri .
            OPTIONAL { _:a countrygroups:groupuri ?groupuri } .
            OPTIONAL { _:a countrygroups:group ?group } .
            _:a countrygroups:spatialcount ?spatialcount .
          }
        }
        
        ?dataUri rdf-syntax:type Data:Data .
      }
    }}
    ORDER BY DESC(?group)
  }
}
ORDER BY DESC(?dataIssued)