Renewable electricity as a percentage of gross electricity consumption, country breakdown, 2012

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX sdmx-measure: <http://purl.org/linked-data/sdmx/2009/measure#> 
PREFIX sdmx-dimension: <http://purl.org/linked-data/sdmx/2009/dimension#> 
PREFIX sdmx-attribute: <http://purl.org/linked-data/sdmx/2009/attribute#> 
PREFIX skos: <http://www.w3.org/2004/02/skos/core#> 
PREFIX property: <http://rdfdata.eionet.europa.eu/eurostat/property#> 
PREFIX geo: <http://rdfdata.eionet.europa.eu/eurostat/dic/geo#>
PREFIX unit: <http://rdfdata.eionet.europa.eu/eurostat/dic/unit#>
PREFIX product: <http://dd.eionet.europa.eu/vocabulary/eurostat/product/>
PREFIX indic_nrg: <http://dd.eionet.europa.eu/vocabulary/eurostat/indic_nrg/>
PREFIX tableFile: <http://semantic.eea.europa.eu/project/indicators/gap_filling_data/ENER030/renewable_electricity_Indicative_target_2010.tsv#>

SELECT
bif:either(?geo = geo:DE, 'Germany', ?ugeo) as ?ugeo
round(sum(?hydro_power)/sum(?total_power)*1000)/10.0 as ?hydro_power
round(sum(?other_renewable)/sum(?total_power)*1000)/10.0 as ?other_renewable
round((sum(?hydro_power)+sum(?other_renewable))/sum(?total_power)*1000)/10.0 as ?renewable
sum(?hydro_power) as ?hydro_power_abs
sum( ?other_renewable) as ?other_renewable_abs
sum(?total_power) as ?total_power_abs
#bif:either(sum(xsd:integer(?target)) = 0, '', sum(xsd:integer(?target))) as ?target
sum(xsd:integer(?target)) as ?target
WHERE {
{  
  GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_105a.rdf.gz> 
  { 
    _:nrg_105a sdmx-dimension:timePeriod ?date . FILTER (year(?date) in (2012))
    _:nrg_105a property:product product:6000 . 
    _:nrg_105a sdmx-attribute:unitMeasure unit:GWH .
    _:nrg_105a property:indic_nrg ?indic_nrg .
    _:nrg_105a sdmx-dimension:refArea ?geo . 
    FILTER (?geo != geo:EA18 and ?geo != geo:EU15 and ?geo != geo:MK and ?geo != geo:RS and ?geo != geo:ME)
    {
      FILTER (?indic_nrg in (indic_nrg:15_107034, indic_nrg:15_107035)) 
      _:nrg_105a sdmx-measure:obsValue ?hydro_power .
    } UNION {
      FILTER (?indic_nrg in (indic_nrg:15_107044, indic_nrg:15_107045,indic_nrg:14_1070421, indic_nrg:14_1070431,indic_nrg:14_1070422, indic_nrg:14_1070432,indic_nrg:15_107038, indic_nrg:15_107039, indic_nrg:15_107040, indic_nrg:15_107041,
indic_nrg:22_108911, indic_nrg:22_108912, indic_nrg:22_108913, indic_nrg:22_108914,indic_nrg:22_108931, indic_nrg:22_108932, indic_nrg:22_108933, indic_nrg:22_108934,indic_nrg:15_107046, indic_nrg:15_107047,indic_nrg:22_108941, 
indic_nrg:22_108942, indic_nrg:22_108943, indic_nrg:22_108944, indic_nrg:22_108951, indic_nrg:22_108952, indic_nrg:22_108953, indic_nrg:22_108954, indic_nrg:22_108971, indic_nrg:22_108972, indic_nrg:22_108973, indic_nrg:22_108974))
      _:nrg_105a sdmx-measure:obsValue ?other_renewable .
    } UNION {
      FILTER (?indic_nrg in (indic_nrg:B_100900, indic_nrg:17_107000)) 
      _:nrg_105a sdmx-measure:obsValue ?total_power .
    }
  }
 } UNION {
 GRAPH <http://semantic.eea.europa.eu/project/indicators/gap_filling_data/ENER030/renewable_electricity_Indicative_target_2010.tsv> 
   { 
     OPTIONAL { _:rec tableFile:geo ?geo } .
     OPTIONAL { _:rec tableFile:target ?target } .
   } 
 }
?geo rdfs:label ?ugeo .
}
GROUP BY ?ugeo ?geo
ORDER BY ?ugeo