Audio-visual, photographic and information processing equipment - Trend in household expenditure for disaggregated electrical and electronic goods, per person and in constant prices, indexed, EU-27, 1996-2012

PREFIX sdmx-measure: <http://purl.org/linked-data/sdmx/2009/measure#> 
PREFIX sdmx-dimension: <http://purl.org/linked-data/sdmx/2009/dimension#> 
PREFIX sdmx-attribute: <http://purl.org/linked-data/sdmx/2009/attribute#> 
PREFIX property: <http://rdfdata.eionet.europa.eu/eurostat/property#> 
PREFIX coicop: <http://rdfdata.eionet.europa.eu/eurostat/dic/coicop#>
PREFIX unit: <http://rdfdata.eionet.europa.eu/eurostat/dic/unit#>
PREFIX geo: <http://rdfdata.eionet.europa.eu/eurostat/dic/geo#>
PREFIX sex: <http://purl.org/linked-data/sdmx/2009/code#>
PREFIX age: <http://rdfdata.eionet.europa.eu/eurostat/dic/age#>

SELECT DISTINCT
year(?date) as ?date
'Audio-visual, photographic and information processing equipment' as ?label
round(( ( sum(?nama_co3_k)/sum(?demo_pjan) ) / ( sum(?nama_co3_k_idx)/sum(?demo_pjan_idx) ) )*1000)/10.0 as ?index 
sum(?nama_co3_k) as ?nama_co3_k
sum(?nama_co3_k_idx) as ?nama_co3_k_idx
sum(?nama_co3_k)/sum(?demo_pjan) as ?pro_capita
sum(?nama_co3_k_idx)/sum(?demo_pjan_idx) as ?pro_capita_idx
sum(?demo_pjan) as ?demo_pjan
sum(?demo_pjan_idx) as ?demo_pjan_idx

WHERE {
{
  GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nama_co3_k.rdf.gz> 
   {
     _:nama_co3_k sdmx-dimension:timePeriod ?date . FILTER (year(?date) >= 1996)
     _:nama_co3_k sdmx-dimension:refArea geo:EU27 . 
     _:nama_co3_k property:coicop coicop:CP091 .
     _:nama_co3_k sdmx-attribute:unitMeasure unit:MIO_EUR_CLV2000 .
     _:nama_co3_k sdmx-measure:obsValue ?nama_co3_k .

     _:nama_co3_k_idx sdmx-dimension:timePeriod ?date_idx . FILTER (year(?date_idx) = 1996)
     _:nama_co3_k_idx sdmx-dimension:refArea geo:EU27 . 
     _:nama_co3_k_idx property:coicop coicop:CP091 .
     _:nama_co3_k_idx sdmx-attribute:unitMeasure unit:MIO_EUR_CLV2000 .
     _:nama_co3_k_idx sdmx-measure:obsValue ?nama_co3_k_idx .
   }
  } UNION {
  GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/demo_pjan.rdf.gz> 
   {
     _:demo_pjan sdmx-dimension:timePeriod ?date . FILTER (year(?date) >= 1996)
     _:demo_pjan sdmx-dimension:refArea geo:EU27 .
     _:demo_pjan sdmx-dimension:age age:TOTAL .
     _:demo_pjan sdmx-dimension:sex sex:sex-T .
     _:demo_pjan sdmx-measure:obsValue ?demo_pjan .

     _:demo_pjan_idx sdmx-dimension:timePeriod ?date_idx . FILTER (year(?date_idx) = 1996)
     _:demo_pjan_idx sdmx-dimension:refArea geo:EU27 .
     _:demo_pjan_idx sdmx-dimension:age age:TOTAL .
     _:demo_pjan_idx sdmx-dimension:sex sex:sex-T .
     _:demo_pjan_idx sdmx-measure:obsValue ?demo_pjan_idx .
   }
  }
 }
GROUP BY ?date